pw_containers/BUILD.gn

# Copyright 2019 The Pigweed Authors
#
# Licensed under the Apache License, Version 2.0 (the "License"); you may not
# use this file except in compliance with the License. You may obtain a copy of
# the License at
#
#     https://www.apache.org/licenses/LICENSE-2.0
#
# Unless required by applicable law or agreed to in writing, software
# distributed under the License is distributed on an "AS IS" BASIS, WITHOUT
# WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied. See the
# License for the specific language governing permissions and limitations under
# the License.

import("//build_overrides/pigweed.gni")

import("$dir_pw_build/target_types.gni")
import("$dir_pw_docgen/docs.gni")
import("$dir_pw_unit_test/test.gni")

config("default_config") {
  include_dirs = [ "public" ]
}

group("pw_containers") {
  public_deps = [
    ":flat_map",
    ":intrusive_list",
    ":vector",
  ]
}

pw_source_set("flat_map") {
  public_configs = [ ":default_config" ]
  public = [ "public/pw_containers/flat_map.h" ]
}

pw_source_set("vector") {
  public_configs = [ ":default_config" ]
  public_deps = [ dir_pw_assert ]
  public = [ "public/pw_containers/vector.h" ]
}

pw_source_set("intrusive_list") {
  public_configs = [ ":default_config" ]
  public = [
    "public/pw_containers/internal/intrusive_list_impl.h",
    "public/pw_containers/intrusive_list.h",
  ]
  sources = [ "intrusive_list.cc" ]
  deps = [ dir_pw_assert ]
}

pw_test_group("tests") {
  tests = [
    ":flat_map_test",
    ":intrusive_list_test",
    ":vector_test",
  ]
}

pw_test("flat_map_test") {
  sources = [ "flat_map_test.cc" ]
  deps = [ ":flat_map" ]
}

pw_test("vector_test") {
  sources = [ "vector_test.cc" ]
  deps = [ ":vector" ]
}

pw_test("intrusive_list_test") {
  sources = [ "intrusive_list_test.cc" ]
  deps = [
    ":intrusive_list",
    "$dir_pw_preprocessor",
  ]
}

pw_doc_group("docs") {
  sources = [ "docs.rst" ]
}